mai.finance 协议清算套利

function liquidateVault(uint256 vaultID) external {

        //1. 确认 vaultID 是否存在
        require(_exists(vaultID), "Vault does not exist");
        //2. 检查该合约是否允许对外开放清算
        require(stabilityPool==address(0) || msg.sender ==  stabilityPool, "liquidation is disabled for public");

        //3. 获取该用户的资产与负债情况
        (uint256 collateralValueTimes100, uint256 debtValue) = calculateCollateralProperties(vaultCollateral[vaultID], vaultDebt[vaultID]);

        uint256 collateralPercentage = collateralValueTimes100.div(debtValue);
        // 4. 资产/负载 的比例需要低于 一定系数才允许清算
        require(collateralPercentage < _minimumCollateralPercentage, "Vault is not below minimum collateral percentage");

        // 5. 对于资产价格的获取,协议用的是 chainlink oracle .
        // oracle 部分资产小数位 只有 8 位 amount(18 位) * price(8 位) 得出来的数字 . 多了 8 位小数点
        // 在 calculateCollateralProperties 方法中, 返回的 debtValue 是进行 * 100000000 处理.已便 正确进行资产运算
        // 所以在这里 / 100000000 来还原 debt 价值
        debtValue = debtValue.div(10 ** priceSourceDecimals);

        // 6. 单次最大可代偿金额
        uint256 halfDebt = debtValue.div(debtRatio); //debtRatio (2)

        // 7. 清算发起方余额需要大于债务余额
        require(mai.balanceOf(msg.sender) >= halfDebt, "Token balance too low to pay off outstanding debt");

        //mai
        // 8. 回收债务
        mai.safeTransferFrom(msg.sender, address(this), halfDebt);

        // 9. 获取可获得的资产数量
        uint256 maticExtract = checkExtract(vaultID);
		// 10. 被清算方减去,清算的资产数量
        vaultDebt[vaultID] = vaultDebt[vaultID].sub(halfDebt); // we paid back half of its debt.
		// 11. 协议方收取 0.5% 的费用
        uint256 _closingFee = (halfDebt.mul(closingFee).mul(getTokenPriceSource()) ).div(getEthPriceSource().mul(10000));

        vaultCollateral[vaultID]=vaultCollateral[vaultID].sub(_closingFee);
        vaultCollateral[treasury]=vaultCollateral[treasury].add(_closingFee);

        // deduct the amount from the vault's collateral
        vaultCollateral[vaultID] = vaultCollateral[vaultID].sub(maticExtract);
        // 12. 记录清算获得的资产,而不是直接分发 , 领取奖励需要调用 getPaid() 方法
        // let liquidator take the collateral
        maticDebt[msg.sender] = maticDebt[msg.sender].add(maticExtract);

        emit LiquidateVault(vaultID, ownerOf(vaultID), msg.sender, halfDebt, maticExtract, _closingFee);
    }